Microsoft Silverlight 4 - Tutoriel 20 : Enregistreur audio

Application d'enregistrement audio en Silverlight

| Peter Bull | Deepin Prayag (Traduction) |

Traducteur

Deepin

Ce tutoriel fait partie d'une série de niveau débutant-intermédiaire pour apprendre Silverlight 4 par le biais d'exemples pas à pas.

Langage : VB.NET

Public visé : niveau Intermédiaire

Commentez ce tutoriel : Commentez

- Titre : Microsoft Silverlight 4 - Tutoriel 20 : Enregistreur audio

- Auteurs : Peter Bull, Deepin Prayag (Traduction)

- Traducteur : Deepin

- Parution : 19 avril 2012

- Mise à jour : 19 avril 2012

- Licence : Copyright ® 2012 Peter Bull. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.

Sommaire

- Traduction

- Introduction

- Application d'enregistrement audio en Silverlight

- Étape 1

- Étape 2

- Étape 3

- Étape 4

- Étape 5

- Étape 6

- Étape 7

- Étape 8

- Étape 9

- Étape 10

- Étape 11

- Étape 12

- Étape 13

- Étape 14

- Étape 15

- Étape 16

- Étape 17

- Étape 18

- Étape 19

- Étape 20

- Étape 21

- Étape 22

- Étape 23

- Étape 24

- Conclusion

- Liens

- Remerciements

Traduction

Ce tutoriel est la traduction la plus fidèle possible du tutoriel original de Peter Bull, Microsoft Silverlight 4 - Audio Recording Application in Silverlight.

Introduction

Audio Recorder est un enregistreur de sons simple utilisant les fonctionnalités AudioCaptureDevice et CaptureSource dans Silverlight 4. Les enregistrements peuvent être sauvegardés en tant que fichier PCM Wave en utilisant un objet AudioSink.

Application d'enregistrement audio en Silverlight

Étape 1

Démarrez Microsoft Visual Web Developer 2010 Express, ensuite sélectionnez Fichier puis Nouveau Projet... Sélectionnez Visual Basic ensuite Application Silverlight dans les modèles installés, sélectionnez un emplacement si vous le souhaitez, puis entrez un nom pour le projet et appuyez sur OK :

Étape 2

Une nouvelle fenêtre Nouvelle application Silverlight devrait apparaître, décochez la case Héberger l'application Silverlight sur un nouveau site Web, puis sélectionnez la Version de Silverlight ciblée :

Étape 3

Une page vierge nommée MainPage.xaml devrait alors apparaître :

Étape 4

Sélectionnez Projet puis Ajouter une classe... et sélectionnez le modèle Classe s'il ne l'est pas déjà, ensuite changez le Nom à MemoryAudioSink.vb :

Étape 5

Ajoutez la nouvelle classe au Projet en cliquant sur Ajouter, ensuite dans la vue de code pour la classe MemoryAudioSink.vb, au-dessus de la ligne Public Class MemoryAudioSink, tapez ceci :

Imports System.IO

Étape 6

Toujours dans la vue de code pour la classe MemoryAudioSink.vb, en dessous de la ligne Public Class MemoryAudioSink, tapez ceci :

Inherits AudioSink
Private _stream As MemoryStream ' Memory Sink
Private _format As AudioFormat ' Recording Format

Étape 7

Pendant que nous en sommes à la vue de code pour la classe MemoryAudioSink, au-dessus du End Class pour Public Class MemoryAudioSink, tapez les Sub suivants :

Protected Overloads Overrides Sub OnCaptureStarted()
_stream = New MemoryStream(1024)
End Sub

Protected Overloads Overrides Sub OnCaptureStopped()
End Sub

Protected Overloads Overrides Sub OnFormatChange(ByVal Format As AudioFormat)
If Format.WaveFormat <> WaveFormatType.PCM Then
Throw New InvalidOperationException("MemoryAudioSink only supports PCM Audio")
End If
_format = Format
End Sub

Protected Overloads Overrides Sub OnSamples(ByVal sampleTime As Long, _
ByVal sampleDuration As Long, _
ByVal sampleData As Byte())
_stream.Write(sampleData, 0, sampleData.Length) ' Write Audio to Stream
End Sub

Étape 8

Puisque nous en sommes toujours à la vue de code pour la classe MemoryAudioSink, au-dessus du End Class pour la classe MemoryAudioSink, tapez les propriétés suivantes :

Public ReadOnly Property BackingStream() As Stream
Get
Return _stream
End Get
End Property

Public ReadOnly Property CurrentFormat() As AudioFormat
Get
Return _format
End Get
End Property

Étape 9

Retournez dans le concepteur de vues pour MainPage en sélectionnant l'onglet MainPage.xaml.

Puis dans la section Tous les contrôles Silverlight de la Boîte à outils, sélectionnez le contrôle Canvas :

Étape 10

Dessinez deux Canvas sur la page, ensuite dans le volet XAML au-dessus de </Grid> modifiez les lignes <Canvas> comme ceci :

<Canvas Height="35" Width="400" VerticalAlignment="Top" HorizontalAlignment="Left" Name="Toolbar"></Canvas>
<Canvas Height="35" Width="400" Margin="0,265,0,0" VerticalAlignment="Top" HorizontalAlignment="Left" Name="StatusBar"></Canvas>

Voir ci-dessous :

Étape 11

Puis dans la section Contrôles Silverlight communs de la Boîte à outils, sélectionnez le contrôle Button :

Étape 12

Dessinez trois boutons sur la barre d'outils du Canvas en glissant les boutons de la Boîte à outils sur le Canvas, ensuite dans le volet XAML entre les balises <Canvas> et </Canvas> modifiez les lignes <Button> comme ceci :

<Button Canvas.Left="6" Canvas.Top="6" Height="23" Width="75" Name="Record" Content="Record"/>
<Button Canvas.Left="87" Canvas.Top="6" Height="23" Width="75" Name="Stop" Content="Stop"/>
<Button Canvas.Left="168" Canvas.Top="6" Height="23" Width="75" Name="Save" Content="Save..."/>

Voir ci-dessous :

Étape 13

Puis dans la section Contrôles Silverlight communs de la Boîte à outils, sélectionnez le contrôle TextBlock :

Étape 14

Dessinez un TextBlock sur le Canvas inférieur (barre d'état) et modifiez la ligne <TextBlock> comme ceci :

<TextBlock Canvas.Left="6" Canvas.Top="6" Height="23" Width="318" FontSize="16" Name="Status"/>

Voir ci-dessous :

Étape 15

Faites un clic droit sur la page ou sur l'entrée pour MainPage.xaml dans l'Explorateur de solutions et choisissez l'option Afficher le code. Dans la vue de code, au-dessus de la ligne Partial Public Class MainPage, tapez le code suivant :

Imports System.IO

Étape 16

Toujours dans la vue de code pour MainPage.xaml, en dessous de la ligne Inherits UserControl, tapez ceci :

Private _source As New CaptureSource
Private _sink As MemoryAudioSink
Private _isRecording As Boolean
Private _hasRecorded As Boolean

Étape 17

Puisque nous en sommes à la vue de code, dans le constructeur Public Sub New() en dessous de la ligne InitializeComponent(), tapez ceci :

_source.AudioCaptureDevice = CaptureDeviceConfiguration.GetDefaultAudioCaptureDevice

Étape 18

Puisque nous en sommes toujours à la vue de code, en dessous du End Sub pour le constructeur Public Sub New(), tapez la fonction et le Sub suivants :

Private Function InlineAssignHelper(Of T)(ByRef target As T, ByVal value As T) As T
target = value
Return value
End Function

Public Sub SavePcmToWav(ByRef Data As Stream, ByRef Output As Stream, _
ByRef Format As AudioFormat)
If Format.WaveFormat <> WaveFormatType.PCM Then
Throw New ArgumentException("Only PCM coding is supported.")
End If
Dim _output As New BinaryWriter(Output)
' WAV header
_output.Write("RIFF".ToCharArray()) ' RIFF chunk
_output.Write(CUInt((Data.Length + 36))) ' Total Length Of Package To Follow
_output.Write("WAVE".ToCharArray()) ' WAV chunk
_output.Write("fmt ".ToCharArray()) ' FORMAT chunk
_output.Write(CUInt(&H10)) ' Length Of FORMAT Chunk (Binary, always 0x10)
_output.Write(CUShort(&H1)) ' Always 0x01
' Channel Numbers (Always 0x01=Mono, 0x02=Stereo)
_output.Write(CUShort(Format.Channels))
_output.Write(CUInt(Format.SamplesPerSecond)) ' Sample Rate (Binary, in Hz)
_output.Write(CUInt((Format.BitsPerSample * _
Format.SamplesPerSecond * _
Format.Channels / 8))) ' Bytes Per Second
' Bytes Per Sample: 1=8 bit Mono, 2=8 bit Stereo or 16 bit Mono, 4=16 bit Stereo
_output.Write(CUShort((Format.BitsPerSample * _
Format.Channels / 8)))
_output.Write(CUShort(Format.BitsPerSample)) ' Bits Per Sample
_output.Write("data".ToCharArray()) ' DATA chunk
_output.Write(CUInt(Data.Length)) ' Length Of Data To Follow
' Raw PCM data
Dim originalPosition As Long = Data.Position ' Remember Original Position
Data.Seek(0, SeekOrigin.Begin) ' Reset position in Data
' Append all data from Data stream into output stream.
Dim buffer As Byte() = New Byte(4095) {}
Dim read As Integer ' number of bytes read in one iteration
While (InlineAssignHelper(read, Data.Read(buffer, 0, 4096))) > 0
_output.Write(buffer, 0, read)
End While
Data.Seek(originalPosition, SeekOrigin.Begin) ' Restore Original Position
End Sub

Étape 19

Retournez au concepteur de vues en sélectionnant l'onglet MainPage.xaml, ou faites un clic droit sur la page ou sur l'entrée pour MainPage.xaml dans l'Explorateur de solutions et choisissez l'option Concepteur de vues.

Double-cliquez sur le contrôle Button « Record » et tapez ceci dans le Sub Record_Click :

If Not _isRecording Then
If (CaptureDeviceConfiguration.AllowedDeviceAccess _
Or CaptureDeviceConfiguration.RequestDeviceAccess) _
And _source.State = CaptureState.Stopped Then
_sink = New MemoryAudioSink
_sink.CaptureSource = _source
_source.Start()
_isRecording = True
_hasRecorded = False
Status.Text = "Recording..."
End If
End If

Étape 20

Retournez au concepteur de vues en sélectionnant l'onglet MainPage.xaml, ou faites un clic droit sur la page ou sur l'entrée pour MainPage.xaml dans l'Explorateur de solutions et choisissez l'option Concepteur de vues.

Double-cliquez sur le contrôle Button « Stop » et tapez ceci dans le Sub Stop_Click :

If _source.State = CaptureState.Started Then
_source.Stop()
_isRecording = False
_hasRecorded = True
Status.Text = "Recording Complete"
End If

Étape 21

Retournez au concepteur de vues en sélectionnant l'onglet MainPage.xaml, ou faites un clic droit sur la page ou sur l'entrée pour MainPage.xaml dans l'Explorateur de solutions et choisissez l'option Concepteur de vues.

Double-cliquez sur le contrôle Button « Save... » et tapez ceci dans le Sub Save_Click :

If _hasRecorded Then
Dim SaveDialog As New SaveFileDialog
SaveDialog.Filter = "Audio Files (*.wav)|*.wav"
If SaveDialog.ShowDialog Then
Try
Status.Text = "Saving..."
Using FileStream As Stream = SaveDialog.OpenFile
SavePcmToWav(_sink.BackingStream, FileStream, _sink.CurrentFormat)
End Using
Status.Text = "Recording Saved"
Catch ex As Exception
' Ignore Errors
End Try
End If
Else
MessageBox.Show("Complete a Recording before Saving", _
"Audio Recorder", MessageBoxButton.OK)
End If

Étape 22

Enregistrez le projet maintenant que vous avez terminé l'application Silverlight. Sélectionnez Debug ensuite Démarrer le débogage ou cliquez sur Démarrer le débogage :

Une fois que vous l'aurez fait, ce qui suit apparaîtra dans une nouvelle fenêtre du navigateur :

Étape 23

Cliquez sur Record, une boîte de dialogue apparaîtra disant : Souhaitez-vous autoriser l'accès à la caméra et au microphone ? Sélectionnez Oui et l'enregistrement devrait commencer. Quand vous aurez terminé, cliquez sur Stop et ensuite sur Save... pour sauvegarder votre enregistrement :

Étape 24

Fermez l'application et la fenêtre du navigateur en cliquant sur le bouton Fermer en haut à droite de la fenêtre de l'application et du navigateur Web pour Arrêter l'application.

Conclusion

Ceci était une application simple basée sur l'audio ou le microphone. Elle pourrait également afficher davantage d'indications visuelles entre la barre d'outils et la barre d'état pour un enregistrement en cours, c'est à vous de voir !

Si vous n'avez pas pu faire fonctionner votre flux audio, essayez de faire un clic droit sur l'application Silverlight, cliquez sur l'option Silverlight, ensuite sélectionnez l'onglet Webcam/Mic pour choisir votre microphone comme la source audio par défaut.

Liens

Télécharger le code source du tutoriel.

Démonstration en ligne du tutoriel.

Remerciements

Je tiens ici à remercier Peter Bull de m'avoir autorisé à traduire son tutoriel.
Je remercie tomlev pour sa relecture technique et ses propositions.
Je remercie également ClaudeLELOUP pour sa relecture orthographique et ses propositions.